Primera visión geométrica compleja

Llamemos, como antes, $N_f$ a la función de Newton asociada a $f$ analítica. Así, si $\{z_n\}_{n\geq0}$ es la sucesión de iterados del método, tenemos $z_{k+1}=N_f(z_k)$. Para evitar confusiones, denotaremos la tercera coordenada $Z$ en lugar de $z$, que denotará la variable compleja. Consideremos la función compleja $F(x,y)=\vert f(x+iy)\vert$. Aunque $F$ es una función de dos variables reales, algunas veces escribiremos $F(z)$, $z=x+iy$, en lugar de $F(x,y)$. Este abuso de notación nos permitirá escribir expresiones más compactas. Sea $T_k$ el plano tangente de $F$ en el punto $(x_k,y_k,F(z_k))$, donde $z_k=x_k+iy_k$, y $R_k$ la recta intersección de $T_k$ con el plano $Z=0$, que llamaremos la traza de $T_k$, cuando esté definida.

Primera interpretación compleja (Teorema 1 en [8])
Supongamos que $z_k$ es tal que $f(z_k)\neq0$ y $f'(z_k)\neq0$, entonces el siguiente iterado de Newton, $z_{k+1}$, es tal que el vector $\stackrel{\longrightarrow\;\;\;\;}{z_kz_{k+1}}$ está en la dirección de $-\nabla\vert f\vert(x_k,y_k)$ y, por lo tanto, $z_{k+1}$ es el punto de $R_k$ que está a distancia mínima de $z_k$.

Este hecho también nos dice que el segmento que une los iterados $z_k$ y $z_{k+1}$ es perpendicular a la traza del plano tangente a $F$ en $z_k$. La demostración de estos hechos se puede leer en [8]. Vamos a comprobarlos gráficamente siguiendo con nuestro ejemplo $f(z)=z^3-1$. Para ello necesitaremos dibujar el plano tangente a la función $F$, su traza y poder visualizar toda esta información de forma conjunta.

Continuando con el ejemplo elegido desde el principio, generamos la información gráfica bidimensional mediante los comandos

ModFzaXY[exprz_] := Sqrt[ZaXY[exprz][[1]]^2 + ZaXY[exprz][[2]]^2]

PTmodf[exprz_, z0_] := Module[{g},
    g = ModFzaXY[exprz];
    (g /. {x -> Re[z0], y -> Im[z0]}) + 
    (D[g, x] /. {x -> Re[z0], y -> Im[z0]})*(x - Re[z0]) +
    (D[g, y] /. {x -> Re[z0], y -> Im[z0]})*(y - Im[z0])
    ]

que dan la expresión simbólica de $\vert f\vert$ y de su plano tangente en un punto elegido. Ahora, junto con el comando Dibu2[ ], estamos preparados para comprobar, en nuestro ejemplo, la afirmación de la primera interpretación geométrica. El dibujo de la traza del plano tangente a $\vert f\vert$, en el punto $0.3+0.5i$, representada mediante un segmento a trazos se consigue mediante

ImplicitPlot[PTmodf[z^3-1,0.3+0.5*I]==0., {x,-1.,1.}, {y,-1.,1.}, 
             PlotStyle->{Dashing[{0.01,0.01}]}]

que junto con el dibujo generado por el comando

Dibu2[z^3-1,0.3+0.5*I,1,-1.5,1.5,-1.5,1.5,PlotPoints->50,Axes->False]

da, como resultado, la Figura 12, donde puede notarse la perpendicularidad de la traza con el segmento que une $z_0=0.3+0.5i$ y $z_1$.

Figura 12: Visión 2D de la primera interpretación compleja

Esta información en el plano puede completarse con el proceso completo en forma tridimensional. Para obtener esta información usaremos las mismas técnicas que hemos aplicado en las secciones anteriores. Además, dibujaremos el plano tangente con el comando

DibPTmodf[exprz_,z0_,varx_,vary_,opt___]:=Module[{dib1,dib2,modf,ptmodf},
    modf=Function[{s, t},ModFzaXY[exprz] /. {x->s, y->t}];
    ptmodf=Function[{s,t}, PTmodf[exprz,z0] /. {x->s, y->t}];
    dib1=Plot3D[ptmodf[x,y],varx,vary,opt,DisplayFunction->Identity];
    dib2=Graphics3D[{PointSize[0.05],
                     Point[{Re[z0],Im[z0],modf[Re[z0],Im[z0]]}]
                    }];
    Show[dib1,dib2,DisplayFunction->$DisplayFunction,
                   AxesLabel->{"x","y",""}]]

Juntando la representación tridimensional de la Figura 12 con el dibujo del plano tangente, generado mediante

DibPTmodf[z^3-1, .3 + 0.5*I, {x,-1.5,1.5}, {y,-1.5,1.5}, PlotRange->{0.,4.}]

obtenemos el dibujo derecho de la Figura 13. La Figura 14 incluye la gráfica de $Z=F(x,y)$ en cada uno de los dibujos de la Figura 13.

Figura 13: Traza y plano tangente

Figura 14: Visión 3D de la primera interpretación compleja